Форум Микро-Чип
Поиск и заказ электронных компонентов
 

Вернуться   Форум Микро-Чип > Вопросы начинающих

Вопросы начинающих Прежде чем задать вопрос, стоит воспользоваться поиском

Закрытая тема
 
Опции темы Опции просмотра
Старый 29.09.2009, 23:08   #1
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Счётчик на PIC16а84 HELP с программой...

Всем доброе время суток =)

Набрёл однажды в интернете на схему счётчика импульсов с пульта ДУ...
И решился её малость переделать... под свои потребности...
в результате получилось ЭТО....


вроде особой разницы нет кроме распиновки индикатора..... (в стандартной прошивке от автора распиновка иная) и замены фотоприёмника на оптрон... ну я особо нечего не переделывал в программе кроме изменения 1,0 портов ввода и вывода... и в результате нефига......
Индикатор не светится, с МК с портов RA0-RA3 идёт 1, хотя для открытия транзилей нужен 0.... на RB0-RB7 постоянно висит 0 на подачу импульса (пробывал и 1 и 0) МК никак не риагирует на Ресет тоже ...... короче полный ппц..

Программа автора (распиновка не подходит под мой индикатор)
Код:
; sprut (zero) Bredendiek 06/2001
;
; 4-stellige RC-5-Anzeige
; Takt 4 MHz
;
; es wird probehalber "rc-5" angezeigt
;
;
; RC5-code hatt 5 Adressenbits (A0-A4) und 7 Commandobits (C0-C6)
; und ist wie folgt als 14-bit code aufgebaut:
;  1. startbit=1
;  2. invertiertes C6
;  3. Toggelbit: wechselt seinen wert von code zu code
;  4. A4
;  5. A3
;  6. A2
;  7. A1
;  8. A0
;  9. C5
; 10. C4
; 11. C3
; 12. C2
; 13. C1
; 14. C0
;
;**************************************************************
; Includedatei fьr den 16F84 einbinden

	#include <P16f84a.INC>

; Variablennamen vergeben

w_copy	Equ	0x20		; Backup fьr Akkuregister
s_copy	Equ	0x21		; Backup fьr Statusregister
Ziffer1	Equ	0x22		; Wert des LSD
Ziffer2	Equ	0x23		; Wert der zweitkleinsten Stelle
Ziffer3	Equ	0x24		; Wert der zweitgrцЯten Stelle
Ziffer4	Equ	0x25		; Wert des MSD
Digit	Equ	0x26		; Ziffernzдhler
ar	Equ	0x27
gr_e	Equ	0x28		; empfangene gruppe
cycl_1	Equ	0x29		; zдhler
cycl_2	Equ	0x2A		; zдhler
cycl_3	Equ	0x2B		; zдhler fьe empfangsbitschleife
data_1	Equ	0x2C		; datenpuffer low-teil
data_2	Equ	0x2D		; datenpuffer high-teil
co_e	Equ	0x2E		; empfangenes commando

;**************************************************************
; los gehts mit dem Programm

	org 	0
	goto	Init	

;**************************************************************
; die Interuptserviceroutine

	org 	4 	
intvec	bcf	INTCON, GIE	; disable Interupt 

	movwf	w_copy		; w retten
	swapf	STATUS, w 	; STATUS retten
	movwf	s_copy		;

	movlw	D'131'		; 256-125=131 ((1MHz : 32 ): 125 = 250 Hz)
	movwf	TMR0

; Intrupt servic routine
Int_serv 

	bsf	PORTA, 0	; Ziffer1 aus
	bsf	PORTA, 1	; Ziffer2 aus
	bsf	PORTA, 2	; Ziffer3 aus
	bsf	PORTA, 3	; Ziffer4 aus

	decf	Digit,f		; Ziffernzдhler verringern
;Digit=4: anzeigen Ziffer 4
;Digit=3: anzeigen Ziffer 3
;Digit=2: anzeigen Ziffer 2
;Digit=1: anzeigen Ziffer 1
;Digit=0: andere Aktionen, keine Anzeige

	btfsc	STATUS, Z
	goto	Int_0		; Z-Flag=1 ergo Digit=0
	movfw	Digit
	movwf	ar
	decf	ar, f
	btfsc	STATUS, Z
	goto	Int_1		; Digit=1
	decf	ar, f
	btfsc	STATUS, Z
	goto	Int_2		; Digit=2
	decf	ar, f
	btfsc	STATUS, Z
	goto	Int_3		; Digit=3
	goto	Int_4		; Digit=4

Int_0
	movlw	5
	movwf	Digit
	goto	Int_end

Int_1
	movfw	Ziffer1		; Wert der 1. Ziffer
	call	Segmente
	movwf	PORTB		; Segmente einschalten
	bcf	PORTA, 0	; 1. Ziffer einschalten
	goto	Int_end

Int_2
	movfw	Ziffer2		; Wert der 2. Ziffer
	call	Segmente
	movwf	PORTB		; Segmente einschalten
	bcf	PORTA, 1	; 2. Ziffer einschalten
	goto	Int_end

Int_3
	movfw	Ziffer3		; Wert der 3. Ziffer
	call	Segmente
	movwf	PORTB		; Segmente einschalten
	bcf	PORTA, 2	; 3. Ziffer einschalten
	goto	Int_end

Int_4
	movfw	Ziffer4		; Wert der 4. Ziffer
	call	Segmente
	movwf	PORTB		; Segmente einschalten
	bcf	PORTA, 3	; 4. Ziffer einschalten
	goto	Int_end


Int_end	swapf	s_copy, w	; STATUS zurьck
	movwf	STATUS 
	swapf	w_copy, f	; w zurьck mit flags
	swapf	w_copy, w

	bcf	INTCON, T0IF	; Interupt-Flag lцschen
	bsf	INTCON, GIE	; enable Interupt

	retfie

; 7-Segment-Tabelle
Segmente
	addwf	PCL, f
	retlw	B'00011000'	; 0
	retlw	B'11011110'	; 1
	retlw	B'00110010'	; 2
	retlw	B'01010010'	; 3
	retlw	B'11010100'	; 4
	retlw	B'01010001'	; 5
	retlw	B'00010001'	; 6
	retlw	B'11011010'	; 7
	retlw	B'00010000'	; 8
	retlw	B'01010000'	; 9
	retlw	B'10010000'	; A
	retlw	B'00010101'	; b
	retlw	B'00111001'	; C
	retlw	B'00010110'	; d
	retlw	B'00110001'	; E
	retlw	B'10110001'	; F
	retlw	B'11101111'	; .
	retlw	B'10110111'	; r
	retlw	B'00110111'	; c
	retlw	B'11110111'	; -
;**************************************************************

; Port A/B auf Ausgabe stellen

Init
	movlw	B'11111111'
	movwf	PORTA
	movwf	PORTB		; Anzeige dunkel
	bsf     STATUS, RP0	; auf Bank 1 umschalten
	movlw	B'11110000'	; PortA RA0-RA3 output
	movwf	TRISA
	movlw	B'00000000'	; PortB alle output
	movwf	TRISB
	bcf     STATUS, RP0	; auf Bank 0 zurьckschalten

	clrf	gr_e
	clrf	co_e

; eine beliebige Zahl einstellen (hier: 'rc-5')
	movlw	5
	movwf	Ziffer1
	movlw	D'19'
	movwf	Ziffer2
	movlw	D'18'
	movwf	Ziffer3
	movlw	D'17'
	movwf	Ziffer4

	movlw	5
	movwf	Digit

; 250 Hz-Timer-Interupt einstellen
	bsf     STATUS, RP0	; auf Bank 1 umschalten
	movlw	B'10000100'	; internen Takt zдhlen, Vorteiler zum Timer0, 32:1
	movwf	OPTION_REG
	movlw	D'131'		; 256-125=131 ((1MHz : 32 ): 125 = 250 Hz)
	bcf     STATUS, RP0	; auf Bank 0 zurьckschalten
	movwf	TMR0
	bsf	INTCON, T0IE	; Timer0 interupt erlauben
	bsf	INTCON, GIE	; Interupt erlauben


;**********************************************************
;**********************************************************
;*
;* pollen der leitung
;*
;* RC-5 bus pollen
;* empfangene signale auf LED ausgeben
;*
;**********************************************************
;**********************************************************

pollen
	call	empfangen	;IR empfangen

	movfw	gr_e		; gruppenadresse 
	andlw	0x0F
	movwf	Ziffer3		; low Teil Gruppe

	swapf	gr_e,w		; gruppenadresse
	andlw	0x0F
	movwf	Ziffer4		; high Teil Gruppe

	movfw	co_e
	andlw	0x0F
	movwf	Ziffer1		; low Teil commando

	swapf	co_e,w		; commando
	andlw	0x0F
	movwf	Ziffer2		; high Teil commando

	call	pause		;2ms warten
	goto	pollen


;**********************************************************
;
; einen RC-5-code mit polling empfangen
;
; gruppencode: gr_e
; commando   : co_e
;
;**********************************************************
; vor dem aufruf wenigstens 1 ms low pegel abwarten !!
empfangen
	btfss	PORTA, 4
	goto	empfangen	; warten auf high

empfangenL
	btfsc	PORTA, 4
	goto	empfangenL	; warten auf low, 1/2-Bit vorbei

	bcf	INTCON,GIE	; interupts sperren

	call	viertelbit	; 1/4 nach bitmitte

	btfsc	PORTA, 4
	goto	Fehler		; war nur spike

	clrf	data_1		; datenpuffer lцschen
	clrf	data_2
	movlw	D'13'		; 13 bits bei syncronisation
	movwf	cycl_3
;
; 3/4 nach bitanfang wird wert gelesen, invertiert
; und eingeschrieben
; dann wird auf die flanke gewartet, die das neue bit einleitet
; nach der flanke wird bis 3/4 bit gewartet und dann neu begonnen
;
	call	halbbit		; 1/4 des 2. Bits

nextbit
	rlf	data_1,f
	rlf	data_2,f
	bcf	data_1, 0	; angenommen leitung ist low (0) 
	btfsc	PORTA, 4	; leitung abfragen
	bsf	data_1, 0	; leitung ist high (1), in datenpuffer

; warten auf pegelдnderung
	call	anders		; Bitmitte

	call	viertelbit	; 3/4 Bit
	call	halbbit		; 1/4 nach bitanfang
	decfsz	cycl_3,f	; alle 13 bit + startbit empfangen?
	goto	nextbit

	movfw	data_1
	movwf	co_e
	bcf	co_e, 6
	bcf	co_e, 7		; auf 6 bit begrenzen

	rlf	data_1,f
	rlf	data_2,f	
	rlf	data_1,f
	rlf	data_2,f	; gruppe nach data_2
	movfw	data_2
	movwf	gr_e
	bcf	gr_e, 7
	bcf	gr_e, 6
	bcf	gr_e, 5		; auf 5 bit begrenzen
	
; 2. stoppbit zum 7 commandobit machen
	btfss	data_2, 6
	bsf	co_e, 6		;2. Stoppbit invers  -> 7.commandobit

	movfw	co_e
Fehler
	bsf	INTCON,GIE	; interrupts wieder erlauben

	return

;**************************************************************
;
; warten darauf, dass die leitung RA0 dem inversen wert in 'data_1, 0' entspricht
;
; zeitbegrenzt auf ca. ein halbes bit
;
;**************************************************************
anders
;	movlw	D'22'		; 22 x (10 MHz)
	movlw	D'9'		; 9 x  ( 4 MHz)
	movwf	cycl_1
a_1
	movlw	D'32'		; 100 takte
	movwf	cycl_2
a_2
	decfsz	cycl_2,f	
	goto	a_2

	btfsc	PORTA, 4	; portpegel abfragen
	goto	a_high
a_low				; portpegel ist 0
	btfsc	data_1, 0	; ist sollwert=0 ?
	return			; high-low flanke
	goto	a_weiter
a_high				; portpegel ist 1
	btfss	data_1, 0	; ist sollwert=1 ?
	return			; low-high flanke
a_weiter
	decfsz	cycl_1,f	
	goto	a_1	
	return			; keine flanke gefunden

;**************************************************************
;
; zeitverzцgerung um ein viertelbit = 444,5 us ca. 1100 takte (10 MHz)
;						445 takte  (04 MHz)
;
; zeitverzцgerung um ein halbbit    = 889 us   ca. 2200 takte (10 MHz)
;						889 takte  (04 MHz)
;
;**************************************************************
pause				;2ms fьr 45
	movlw	D'45'
	goto	l_0
pause_l				;ca 12ms fьr 255
	movlw	D'255'
	goto	l_0
viertelbit
;	movlw	D'11'		; 11 x (10 MHz)
	movlw	D'9'		; 9 x  ( 4 MHz)
	goto	l_0
halbbit
;	movlw	D'22'		; 22 x (10 MHz)
	movlw	D'18'		; 18 x ( 4 MHz)
l_0
	movwf	cycl_1
l_1

;	movlw	D'32'		; 100 takte (10 MHz)
	movlw	D'15'		; 49 takte  ( 4 MHz)
	movwf	cycl_2
l_2
	decfsz	cycl_2,f	
	goto	l_2

	decfsz	cycl_1,f	
	goto	l_1	
	return

	end
ПОМОГИТЕ!!!! надо переделать программу приложеную автором под мою цель - подсчёт поданых логических 1 на порт RA4 с оптрона и отображение в 10 системе на индикаторе..... Для того что-бы управлять выводами отвечающими за 7 сегментов надо подавать на сегменты 0, что-бы управлять выбором сегментной сборки, так-же необходимо подавать с МК логический 0....
Проще говоря нужен приметивный счётчик который будет суммировать полученые 1 =)

Я понимаю что "каждый программист должен париться сам" но МК занимаюсь недавно, а с АСМ сталкиваюсь в первые.... до этого работал с PB Pro .... написал -бы сам, но немогу понять как можно отображать одновременно 4 цифры, и при этом что-бы все цифры были разные....... с таким индикатором сталктваюсь в первые....
Миниатюры
1212.jpg  

Последний раз редактировалось ChiperKO; 29.09.2009 в 23:25.
ChiperKO вне форума  
Старый 29.09.2009, 23:33   #2
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

*В заголовке поста опечатался.... у меня микруха PIC16F84A
ChiperKO вне форума  
Старый 29.09.2009, 23:39   #3
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

что-то всего много... по порядку.
импульсы на ключах присутствуют?
pic стартует?
AlexPv вне форума  
Старый 29.09.2009, 23:41   #4
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

да на выводах RA0-RA3 есть импульс => транзиля закрыты......
Исходя из этого пик стартанул....
ChiperKO вне форума  
Старый 29.09.2009, 23:47   #5
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

перечитал пост - похоже, мк не стартует. как вариант проверить авторскую прошивку. правильно-ли прошито конфигурационное слово? и кварц без конденсаторов подозрительно смотриться, возможно он и не возбуждается. блокировочных кондеров почему нет?
AlexPv вне форума  
Старый 29.09.2009, 23:48   #6
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Цитата:
Сообщение от ChiperKO Посмотреть сообщение
да на выводах RA0-RA3 есть импульс => транзиля закрыты......
Исходя из этого пик стартанул....
ну а транзисторы он открывает
AlexPv вне форума  
Старый 29.09.2009, 23:49   #7
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

два конденсатора по 15 пикофорат повесил....
С АСМ работаю в первые и понятия не имею как проверить конфиг...
ChiperKO вне форума  
Старый 29.09.2009, 23:53   #8
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Цитата:
Сообщение от AlexPv Посмотреть сообщение
ну а транзисторы он открывает
как он логической единицой откроет обратный транзистор? надо что-бы был 0 а он его не даёт.....
ChiperKO вне форума  
Старый 29.09.2009, 23:53   #9
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

индикатор с общим анодом или катодом замкните к-э любого транзистора - должны светится сегменты там где на порту б 0.
извиняюсь за качество текста - с мобилы пишу
AlexPv вне форума  
Старый 29.09.2009, 23:54   #10
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Цитата:
Сообщение от ChiperKO Посмотреть сообщение
как он логической единицой откроет обратный транзистор? надо что-бы был 0 а он его не даёт.....
так там импульсы или все время единица висит?
AlexPv вне форума  
Старый 29.09.2009, 23:56   #11
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

общеанодный индикатор как паложено......
ChiperKO вне форума  
Старый 29.09.2009, 23:59   #12
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Ну, а с импульсами как?


OFF: Перешел на "большой" комп, теперь нормально можно печатать, все кпк - г-но.
AlexPv вне форума  
Старый 30.09.2009, 00:01   #13
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

а RA0-RA3 висят единицы, поэтому +5в на анод не попадает..
ChiperKO вне форума  
Старый 30.09.2009, 00:02   #14
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Ну, так вот:
Если на PORTB – 0, на RA0-RA3 – 1 (постоянно), очень похоже, что микроконтроллер не стартует.
А лог.1 будет за счёт прямого смещения ЭБ p-n перехода.
Можно простенькую тест-программку написать и зашить, которая будет играть ногами потра.
AlexPv вне форума  
Старый 30.09.2009, 00:04   #15
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Кстати, в листинге в упор не вижу конфигурационого слова.
AlexPv вне форума  
Старый 30.09.2009, 00:04   #16
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Можешь писануть простую тест прогу... пожалуйста?)

P.S. что-бы число светилось нужно и на RA и на RB подавать 0 .....
ChiperKO вне форума  
Старый 30.09.2009, 00:09   #17
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

тебе в помощ..


; 0 Segment A
;* 1 Segment B
;* 2 Segment C
;* 3 Segment D
;* 4 Segment E
;* 5 Segment F
;* 6 Segment G
;* 7 Segment точка
ChiperKO вне форума  
Старый 30.09.2009, 00:27   #18
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

В общем так: в rcr5test.hex нет конфиг. слова. IC-prog ставит по умолчанию RC-генератор, WDT_ON. А в схеме кварц на 4MHz. Поставь кварц в соответствии со схемой. (33пФ)
Между ногами 14 и 5 включить пленочный конденсатор 0,1 мкФ.
В программу добавь слово конфигурации (как в примере)
__CONFIG _CP_OFF & _WDT_OFF & _XT_OSC ;конфигурация микроконтроллера
Скомпилируй и прошей по новой.
Миниатюры
ZQ.JPG  

Последний раз редактировалось AlexPv; 30.09.2009 в 00:36.
AlexPv вне форума  
Старый 30.09.2009, 00:33   #19
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Шил WinPIC 800
частота 4 МГ
ChiperKO вне форума  
Старый 30.09.2009, 00:35   #20
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Что-то глючит Mplab IDE.... откомпелируй пожалуста... и выложи HEX
ChiperKO вне форума  
Старый 30.09.2009, 00:40   #21
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Цитата:
Сообщение от ChiperKO Посмотреть сообщение
Что-то глючит Mplab IDE.... откомпелируй пожалуста... и выложи HEX
Вот проектик, зажигает три каких-то сегмента первого разряда.
Извиняюсь за синтаксис давно на си пишу для авров + позднее время.

У файла убрать расширение .pdf (это rar-архив)
Вложения
Тип файла: pdf Test.rar.pdf (7.9 Кб, 8 просмотров)

Последний раз редактировалось AlexPv; 30.09.2009 в 00:58.
AlexPv вне форума  
Старый 30.09.2009, 00:53   #22
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Спасибо!!!! счас прошю и пойду спать =) у меня в городе уже 3 утра...
Вот фотки проекта......


P.S ещё не успел спиртиком почистить платку))
Завтра отпишу о результате.....
Миниатюры
DC090930001.jpg   DC090930002.jpg  
ChiperKO вне форума  
Старый 30.09.2009, 01:06   #23
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Цитата:
Сообщение от ChiperKO Посмотреть сообщение
Что-то глючит Mplab IDE.... откомпелируй пожалуста... и выложи HEX
Не Mplab IDE глючит, а я . В тех примерах есть ошибки, в архиве Test.rar, исправленный листинг (кривой, но вроде рабочий ) и откомпилированный .hex файл с прописанной конфигурацией.
AlexPv вне форума  
Старый 30.09.2009, 01:12   #24
ChiperKO
Senior Member
 
Регистрация: 29.09.2009
Адрес: Москва
Сообщений: 118
Вес репутации: 123/40
ChiperKO will become famous soon enoughChiperKO will become famous soon enough
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

архив битый =( вин рар ругается.... и хекс почемуто всего в 1 строку?
ChiperKO вне форума  
Старый 30.09.2009, 01:16   #25
AlexPv
Senior Member
 
Регистрация: 02.03.2009
Адрес: Russia
Сообщений: 1,800
Вес репутации: 565/63
AlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to allAlexPv is a name known to all
По умолчанию Re: Счётчик на PIC16а84 HELP с программой...

Странно, у меня норм. скачивается. Переименовать расш. .rar
Перезалил.
Вложения
Тип файла: pdf Test1.rar.pdf (91.9 Кб, 11 просмотров)
AlexPv вне форума  
Закрытая тема


Здесь присутствуют: 1 (пользователей: 0 , гостей: 1)
 
Опции темы
Опции просмотра

Ваши права в разделе
Вы не можете создавать новые темы
Вы не можете отвечать в темах
Вы не можете прикреплять вложения
Вы не можете редактировать свои сообщения

BB коды Вкл.
Смайлы Вкл.
[IMG] код Вкл.
HTML код Выкл.

Быстрый переход

Похожие темы
Тема Автор Раздел Ответов Последнее сообщение
Присоветуйте тип и способ управления MOSFETом "верхнего" плеча dr_Sash Источники питания и силовая электроника 37 08.09.2012 18:50
Библиотека готовых решений на PIC18f Assembler : работа с датчиком температуры DS18b20... dr_Sash Продукция MICROCHIP 61 12.01.2012 22:36
солнечные батарейки + АКБ на 4*190А +4*50А Tigran_ss Источники питания и силовая электроника 17 21.08.2009 17:02
помогите переложить рабочую прог с P16F628 на 12f629 gen22 Общетехнические вопросы 3 15.06.2009 14:27
Написал программу а места не хватает на МК Аександр Продукция MICROCHIP 150 10.01.2008 12:33


Часовой пояс GMT +3, время: 18:52.


Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2019, Jelsoft Enterprises Ltd. Перевод: zCarot